#!/usr/bin/awk -f
# name : mef2html
# categorie : html
# version : 1.6
# date : 12/02/2015
# historique:         06/11/2014 1.0 initial          
#			10/11/2014 1.1 liste et puces, liste de définition
#                              14/11/2014 1.2 ajout tags html (<ins>, <exp> ...)
#			14/11/2014 1.3 ajout de la date et de l'heure	
#			20/11/2014 1.4 ajout de @link 'non générique)
#                              02/12/2014 1.5 @tab avec couleur
#			03/12/2014 1.5.1 documentation associée
#			10/12/2014 1.5.2 tags en plus small,mark
#			15/12/2014 1.5.3 affichage de la version, meilleure documentation
#			16/12/2014 1.5.4 commentaires
#			14/01/2015 1.5.5 @lip/ ajouté
#			12/02/2015 1.6 correction bug tab: split ne retourne pas une valeur ordonnée
#---------------------------------------------------------------
function version()
{
  print "mef2html.awk"   	
  print "version 1.6"
  print "12/02/2015"
  print "J.L BICQUELET"		
}
#---------------------------------------------------------------
function usage()
{
  print "USAGE"
  print "-----\n"
  
  print "1. awk -f mef2html.awk fichier"
  print "convertit en html fichier"
  print
  print "2. awk -f mef2html.awk usage ou awk -f mef2html.awk /?" 
  print "affiche l'usage"
  print
  print "3. awk -f mef2html.awk doc ou awk -f mef2html.awk /d"
  print "affiche la documentation en html"
  print
  print "4. awk -f mef2html.awk ver ou awk -f mef2html.awk /v"
  print "affiche la version de mef2html"
  print
  print "BLOCS"
  print "-----\n"
  for (i=1;i<=6;i++) { printf ("@h%d/ header niveau %d\n",i,i) }
  print
  print "@tab/ ou @table/ début de tableau"
  print "@tab  ou @table  fin de tableau"
  print "les colonnes sont séparées par un caractère défini par la variable [sep]."
  print "la taille de la bordure est fixée par la variable [border]."
  print
  print "@screen/ ou @scr/ ou @cons/ début du mode console"
  print "@screen  ou @scr  ou @cons  fin du mode console"

  print
  print "@code/ ou @lst/  début du mode listing"
  print "@code  ou @lst  fin du mode listing"
  print
  print "@list/   début d'une liste"
  print "@list    fin d'une liste"
  print
  print "@download/   début d'un tableau de download"
  print "@download    fin d'un tableau de download"
  print
  print "@system/   execute une commande et insère le résultat"
  print "@include/  insère un fichier"
  print  
  print "TAGS"
  print "----\n"
  for (j=0;j<nb_tags;j++) { print tag[j] ") - " comment[j] }
  print
  
  print "VARIABLES"
  print "---------\n"
  print "@border= bordure d'un tableau (0,1,2,..)"
  print "@sep=    séparateur de colonne dans un tableau (; . : ...)"
  print "@puce=   type de puce : disc, square, circle"
  print
  print "@bicolor=0 tableau sans couleur"
  print "@bicolor=1 tableau avec couleur de fond color1 et color2"
  print "@color1= couleur format #F7F7F7 par exemple"
  print "@color2= couleur format #A7A7A7 par exemple"
  print 
  print "INTERNE"
  print "-------\n"
  print
  print "Les commentaires sont insérés avec une ligne commençant par ::"
  print
}

#---------------------------------------------------------------
function documentation()
{
  print "<h2>USAGE</h2>"
  print "<p><b>mef2html.awk</b> s'utilise de 3 manières possibles"
  print "<p><ol>"
  
  print "<li><b>awk -f mef2html.awk fichier</b>"
  print "<br>convertit en html fichier"
  print "<p>"
  print "<li><b>awk -f mef2html.awk usage (ou <b>/?</b>)</b>"
  print "<br>affiche l'usage"
  print "<p>"
  print "<li><b>awk -f conv.awk doc</b> (ou <b>/d</b>)"
  print "<br>affiche une documentation en html"
  print "<p>"
  print "<li><b>awk -f conv.awk version</b> (ou <b>/v</b>)"
  print "<br>version du programme"
  print "</ol>"
  
  print "<h2>PRINCIPES</h2>"
  print "<ul><li><p>Les tags utilisés par <b>mef2html.awk</b> commencent toujours par le caractère <b>@</b>."
  print "<li><p>Les tags se terminant par <b>/</b> correspondent à des commandes de blocs."
  print "<br>si le tag est <b>@key/</b> , le bloc se termine par <b>@key</b> et le formattage s applique au bloc définit."
  print "<li><p>Les tags délimités par  <b>(</b> <b>)</b> correspondent à des fonctions soit de mise en forme de texte, soit des fonctions fournissant une chaine (heure, date par exemple)."
  print "<li><p>Les tags se terminant par un <b>=</b> indique des affectations de variables ou des directives de mise en forme."
  print "</ul>"
    
  print "<h2>BLOCS</h2>"
  print "<p>Les tags définissant les blocs sont:<br>"

    for (i=1;i<=6;i++) { printf ("<br><b>@h%d/</b> header niveau %d\n",i,i) }
  print
  print "<p><b>@tab/</b> ou <b>@table/</b> début de tableau"
  print "<br><b>@tab</b>  ou <b>@table</b>  fin de tableau"
  print "<p>les colonnes sont séparées par un caractère défini par la variable [sep]."
  print "<br>la taille de la bordure est fixée par la variable [border]."
  print
  print "<p><b>@screen/</b> ou <b>@scr/</b> ou <b>@cons/</b> début du mode console"
  print "<br><b>@screen</b>  ou <b>@scr</b>  ou <b>@cons</b>  fin du mode console"
  print 
  print "<p><b>@code/</b> ou <b>@lst/</b>  début du mode listing"
  print "<br><b>@code</b>  ou <b>@lst</b>  fin du mode listing"

  print
  print "<p><b>@list/</b>   début d'une liste"
  print "v@list</b>    fin d'une liste"
  print
  print "<p><b>@download/</b>   début d'un tableau de download"
  print "<br><b>@download</b>    fin d'un tableau de download"
  print
  print "<p><b>@system/</b>   execute une commande et insère le résultat"
  print "<br><b>@include/</b>  insère un fichier"
  print  
  
  print "<h2>TAGS</h2>"
 print "Les tags de mise en forme du texte:<br>"
  for (j=0;j<nb_tags;j++) { print "<br><b>" tag[j] ")</b> - " comment[j] }
  print
  
  print "<h2>VARIABLES</h2>"
 print "<p> Les variables et directives que l'on peut définir pour la mise en forme sont:"
  print "<p>"
  print "<p><b>@border=</b> bordure d'un tableau (0,1,2,..)"
  print "<br><b>@sep=</b>    séparateur de colonne dans un tableau (; . : ...)"
  print "<br><b>@puce=</b>   type de puce : disc, square, circle"
  print "<br>"
  print "<br><b>@bicolor=0 </b>tableau sans couleur"
  print "<br><b>@bicolor=1</b> tableau avec couleur de fond color1 et color2"
  print "<br><b>@color1=</b> couleur format #F7F7F7 par exemple"
  print "<br><b>@color2=</b> couleur format #A7A7A7 par exemple"
  print
 print "<h2>INTERNE<h2>"
    print
  print "<p>Les commentaires sont insérés avec une ligne commençant par ::"
  print
}

#---------------------------------------------------------------
function right(str,pos)
{
  return substr(str,pos,length(str)-pos+1)
}

#------------------------------------------------------------------
# replace(str,ch,rep,rep2) - remplace ch par rep ch rep2 dans str
#------------------------------------------------------------------
function replace(str,ch,rep,rep2)
{
  s=1
  size=length(ch)
  while(s>0) {
    s=index(str,ch)
    if (s==0) { break; }
    e=index(str,")")
    str=substr(str,1,s-1) rep substr(str,s+size,e-s-size) rep2 substr(str,e+1,length(str)-e)
  }
  return str
}

#------------------------------------------------------------------
# replace_function_2args(str,ch,rep1,rep2,rep3) - remplace ch par rep ch rep2 dans str
#------------------------------------------------------------------
function replace_function_2args(str,ch,rep1,rep2,rep3)
{
 
  s=1
  while(s>0) {
   
   s=index(str,ch)
   if (s>0) { str=rep_link(str,ch,rep1,rep2,rep3) }
  }
  
  return str
}

function  rep_link(str,ch)
{
  a=index(str,ch)
  b=index(str,",")
  c=index(str,")")
  l=length(ch)
  v=substr(str,1,a-1) "<a href=\"" substr(str,a+l,b-a-l) "\">" substr(str,b+1,c-b-1) "</a>" substr(str,c+1,length(s)-c)
 #  v=substr(str,1,a-1) rep1 substr(str,a+l,b-a-l) "\">" substr(str,b+1,c-b-1) "</a>" substr(str,c+1,length(s)-c)
  return v 
}

#---------------------------------------------------------------
function replace_one(str,ch,rep)
{
  s=1
  size=length(ch)
  lg=length(str)
  while(s>0) {
    s=index(str,ch)
    if (s==0) { break; }
    str=substr(str,1,s-1) rep substr(str,s+size,lg-s-size+1)
  }
  return str
}

#---------------------------------------------------------------
# alen(array) -- retourne le nombre d'éléments d'un tableau
#---------------------------------------------------------------
function alen(array) {
    len=0
    for (dummy in array)
        len++;

    return len;
}

#---------------------------------------------------------------
# gettimeofday.awk --- get the time of day in a usable format

# Returns a string in the format of output of date(1)
# Populates the array argument time with individual values:
#    time["second"]       -- seconds (0 - 59)
#    time["minute"]       -- minutes (0 - 59)
#    time["hour"]         -- hours (0 - 23)
#    time["althour"]      -- hours (0 - 12)
#    time["monthday"]     -- day of month (1 - 31)
#    time["month"]        -- month of year (1 - 12)
#    time["monthname"]    -- name of the month
#    time["shortmonth"]   -- short name of the month
#    time["year"]         -- year modulo 100 (0 - 99)
#    time["fullyear"]     -- full year
#    time["weekday"]      -- day of week (Sunday = 0)
#    time["altweekday"]   -- day of week (Monday = 0)
#    time["dayname"]      -- name of weekday
#    time["shortdayname"] -- short name of weekday
#    time["yearday"]      -- day of year (0 - 365)
#    time["timezone"]     -- abbreviation of timezone name
#    time["ampm"]         -- AM or PM designation
#    time["weeknum"]      -- week number, Sunday first day
#    time["altweeknum"]   -- week number, Monday first day

function date()
{
    now = systime()
    ret = strftime("%d/%m/%Y", now)
	print ret
}

function time2()
{
    now = systime()
    ret = strftime("%H:%M:%S", now)
	print ret
}
	
function dateex(mode)
{

    # return date(1)-style output
    ret = strftime("%a %b %d %H:%M:%S %Z %Y", now)

    # clear out target array
    delete time

    # fill in values, force numeric values to be
    # numeric by adding 0
    time["second"]       = strftime("%S", now) + 0
    time["minute"]       = strftime("%M", now) + 0
    time["hour"]         = strftime("%H", now) + 0
    time["althour"]      = strftime("%I", now) + 0
    time["monthday"]     = strftime("%d", now) + 0
    time["month"]        = strftime("%m", now) + 0
    time["monthname"]    = strftime("%B", now)
    time["shortmonth"]   = strftime("%b", now)
    time["year"]         = strftime("%y", now) + 0
    time["fullyear"]     = strftime("%Y", now) + 0
    time["weekday"]      = strftime("%w", now) + 0
    time["altweekday"]   = strftime("%u", now) + 0
    time["dayname"]      = strftime("%A", now)
    time["shortdayname"] = strftime("%a", now)
    time["yearday"]      = strftime("%j", now) + 0
    time["timezone"]     = strftime("%Z", now)
    time["ampm"]         = strftime("%p", now)
    time["weeknum"]      = strftime("%U", now) + 0
    time["altweeknum"]   = strftime("%W", now) + 0

 #   print time[mode]	
	print ret
}


#---------------------------------------------------------------
# gestion des tableaux
#---------------------------------------------------------------
function raw(str,sep)
{
  n=split(str,word,sep)
  if(bicolor==0) {
    printf  "<tr>"
    for (i=1;i<=n;i++) printf "<td>" word[i] "</td>"
      print "</tr>"
  }
  else { if (nbl == 0) {color=color1 ; nbl=1 } else { color=color2 ; nbl=0}
    printf  ("<tr bgcolor=\"%s\">",color)
       for (i=1;i<=n;i++) printf  ("<td bgcolor=\"%s\">%s</td>" ,color,word[i])
      print "</tr>"
     
  }
}

#---------------------------------------------------------------
# gestion des fichiers à télécharger
#---------------------------------------------------------------
function download(str,sep)
{
  delete word
  split(str,word,sep)
  printf  "<tr>"
  for (i=1; i<alen(word);i++) { printf "<td>" word[i] "</td>" }
  printf "<td><a href=\"" dir  word[i] "\">" word[i] "</a></td>"
  printf "</tr>\n"
}

#---------------------------------------------------------------
function readfile2(file)
{
    save_rs = RS
    RS = "^$"
    getline tmp < file
    close(file)
    RS = save_rs

    return tmp
}

#---------------------------------------------------------------
function readfile(file)
{
    if ((getline tmp < file) < 0)
        return

    print tmp
    while ((getline tmp < file) > 0)
        print tmp
    close(file)
    return
}

#---------------------------------------------------------------
function process(str)
{
  str=replace_function_2args(str,"@link(","<href=\"","\">","</a>")


  for (i=0;i<nb_tags;i++) {
    str=replace(str,tag[i],rep[i],rep2[i])
  }
  for (i=0;i<nb_repl;i++) {
    str=replace_one(str,find[i],repl[i])
  }

  #str=replace_one(str,"@date/",date())

 return str
}

#---------------------------------------------------------------
function parse_args()
{
   FLAG_TEXT=0
#   for(i=0;i<ARGC;i++)
#         print(i,ARGV[i])
   if ((ARGV[1]=="usage") || (ARGV[1]=="/?"))
   {
     usage()
     exit;
   }
   if ((ARGV[1]=="doc")|| (ARGV[1]=="/d"))
   {
     documentation()
     exit;
   }
  if ((ARGV[1]=="version") || (ARGV[1]=="ver")|| (ARGV[1]=="/v"))
   {
     version()
     exit;
   }
   if (ARGV[1]=="text")
   {
     ARGV[1]=ARGV[2];
	 ARGC--;
	 FLAG_TEXT=1
   }
}
#=====================================================================
BEGIN { 
mode=0
sep=";"
border=0
bicolor=1
nbl=0
color2="#F0F0F0"
color1="#A0A0A0"
dir="src\\"

puce="disc";
type_list="ord"
# http://cyberzoide.developpez.com/html/list.php3#type

i=0
tag[i]= "@ins(" ; comment[i] ="ajout de texte" ; rep[i]= "<ins>" ; rep2[i++]="</ins>" 
tag[i]= "@del(" ; comment[i] ="suppresion de texte" ; rep[i]= "<del>" ; rep2[i++]="</del>" 
tag[i]= "@sup(" ; comment[i] ="exposant" ; rep[i]= "<sup>" ; rep2[i++]="</sup>" 
tag[i]= "@sub(" ; comment[i] ="indice" ; rep[i]= "<sub>" ; rep2[i++]="</sub>" 
tag[i]= "@em(" ; comment[i] ="emphase" ; rep[i]= "<em>" ; rep2[i++]="</em>" 
tag[i]= "@small(" ; comment[i] ="small" ; rep[i]= "<small>" ; rep2[i++]="</small>" 
tag[i]= "@mark(" ; comment[i] ="marque" ; rep[i]= "<mark>" ; rep2[i++]="</mark>" 
tag[i]= "@strong(" ; comment[i] ="strong" ; rep[i]= "<strong>" ; rep2[i++]="</strong>" 
tag[i]= "@abbr(" ; comment[i] ="abréviation" ; rep[i]= "<abbr>" ; rep2[i++]="</abbr>" 
tag[i]= "@acronym(" ; comment[i] ="acronym" ; rep[i]= "<acronym>" ; rep2[i++]="</acronym>" 
tag[i]= "@acro(" ; comment[i] ="acronym" ; rep[i]= "<acronym>" ; rep2[i++]="</acronym>" 
tag[i]= "@def(" ; comment[i] ="définition" ; rep[i]= "<def>" ; rep2[i++]="</def>" 
tag[i]= "@citation(" ; comment[i] ="citation" ; rep[i]= "<cite>" ; rep2[i++]="</cite>" 
tag[i]= "@kbd(" ; comment[i] ="touche clavier" ; rep[i]= "<kbd>" ; rep2[i++]="</kbd>" 
tag[i]= "@var(" ; comment[i] ="variable" ; rep[i]= "<var>" ; rep2[i++]="</var>" 
tag[i]= "@samp(" ; comment[i] ="exemple de sortie" ; rep[i]= "<samp>" ; rep2[i++]="</samp>" 
tag[i]= "@address(" ; comment[i] ="addresse" ; rep[i]= "<address>" ; rep2[i++]="</address>" 

tag[i]= "@b(" ; comment[i] ="gras" ; rep[i]= "<b>" ; rep2[i++]="</b>" 
tag[i]= "@i(" ; comment[i] ="italique" ; rep[i]= "<i>" ; rep2[i++]="</i>"
tag[i]= "@u(" ; comment[i] ="souligné" ; rep[i]= "<u>" ; rep2[i++]="</u>"
tag[i]= "@s(" ; comment[i] ="barré" ; rep[i]= "<s>" ; rep2[i++]="</s>"
tag[i]= "@cr(" ; comment[i] ="couleur rouge" ; rep[i]= "<font color=\"red\">" ; rep2[i++]="</font>"
tag[i]= "@cb(" ; comment[i] ="couleur bleu" ; rep[i]= "<font color=\"blue\">" ; rep2[i++]="</font>"
tag[i]= "@cv(" ; comment[i] ="couleur verte" ; rep[i]= "<font color=\"green\">" ; rep2[i++]="</font>"
tag[i]= "@cn(" ; comment[i] ="couleur noiree" ; rep[i]= "<font color=\"black\">" ; rep2[i++]="</font>"
tag[i]= "@cj(" ; comment[i] ="couleur jaune" ; rep[i]= "<font color=\"yellow\">" ; rep2[i++]="</font>"
tag[i]= "@cw(" ; comment[i] ="couleur blanche"  ; rep[i]= "<font color=\"white\">" ; rep2[i++]="</font>"
nb_tags=i

j=0
find[j]="@ol/" ; comment[i] ="début liste numérotée"  ; repl[j++]="<ol>";
find[j]="@ol" ; comment[i] ="fin liste numérotée"  ;repl[j++]="</ol>";
find[j]="@ul/" ; comment[i] ="début liste ordonnée"  ;repl[j++]="<ul>";
find[j]="@ul" ; comment[i] ="fin liste ordonnée"  ; repl[j++]="</ul>";
find[j]="@lh/" ; comment[i] ="tete de liste" ; repl[j++]="<lh>";
find[j]="@lip/" ; comment[i] ="liste avec paragraphe" ; repl[j++]="<li><p>";
find[j]="@li/" ; comment[i] ="liste" ; repl[j++]="<li>";
find[j]="@li" ; comment[i] ="fin de liste" ; repl[j++]="</li>";
find[j]="@dl/" ; comment[i] ="liste de définition" ; repl[j++]="<dt>";
find[j]="@dl" ; comment[i] ="fin de liste de définition" ; repl[j++]="</dl>";
find[j]="@dt/" ; comment[i] ="terme" ; repl[j++]="<dl>";
find[j]="@dd/" ; comment[i] ="définition" ; repl[j++]="<dd>";
find[j]="@pre/" ; comment[i] ="break" ; repl[j++]="<pre>";
find[j]="@pre" ; comment[i] ="break" ; repl[j++]="</pre>";
find[j]="@br/" ; comment[i] ="break" ; repl[j++]="<br>";
find[j]="@p/" ; comment[i] ="paragraphe" ; repl[j++]="<p>";
find[j]="@p" ;  comment[i] ="fin paragraphe" ; repl[j++]="</p>";
nb_repl=j

parse_args()
}
#=============================================================================
#-----------------------------------------------------------------------------
# commentaires 
#-----------------------------------------------------------------------------

/^::/ { next }

#-----------------------------------------------------------------------------
# header
#-----------------------------------------------------------------------------
/^@h1\// { print "<h1>" right($0,5) "</h1>"; next }
/^@h2\// { print "<h2>" right($0,5) "</h2>"; next }
/^@h3\// { print "<h3>" right($0,5) "</h3>"; next }
/^@h4\// { print "<h4>" right($0,5) "</h4>"; next }
/^@h5\// { print "<h5>" right($0,5) "</h5>"; next }
/^@h6\// { print "<h6>" right($0,5) "</h6>"; next }

/^@que\// { print "<h4>" right($0,6) "</h4>"; next }

#-----------------------------------------------------------------------------
#system, include, date
#-----------------------------------------------------------------------------
/@system\// {  split($0,val,"/");   system(val[2]) ; next }
/@include\// {  split($0,val,"/");   readfile(val[2]) ; next }

#-----------------------------------------------------------------------------
# tableaux
#-----------------------------------------------------------------------------
/@tab\// { printf("<table border=%s>",border) ; mode =2; nbl=0; next}
/@tab/ { print "</table>" ; mode =0; next}
/@table\// { printf("<table border=%s>",border) ; mode =2; nbl=0; next}
/@table/ { print "</table>" ; mode =0; next}

/@download\// { printf"<table border=\"1\">" 
                print "<tr><th>librairie</th><th>version</th><th>date</th><th>fichier</th></tr>"
               ;mode =5; next}
/@download/ { print "</table>" ; mode =0; next}

# /@date\// { date("dayname") ; next}

#-----------------------------------------------------------------------------
# codes
#-----------------------------------------------------------------------------
/(@code\/|@lst\/)/ { print "<p><pre class=\"codeblock\">" ; mode=0 ; next }
/@code|@lst/ { print "</pre><p>"; next }
/(@screen\/|@scr\/|@cons\/)/ { print "<p><pre class=\"screen\">" ; mode=0 ; next }
/@screen|@scr|@cons/ { print "</pre><p>"; next }

#-----------------------------------------------------------------------------
# listes
#-----------------------------------------------------------------------------
/@list\// { print "<ul type=\"" puce "\" >" ; mode=4 ; next }
/@list/ { print "</ul>"; mode=0 ; next}

#-----------------------------------------------------------------------------
# controle des variables
#-----------------------------------------------------------------------------
/@sep=/ { split($0,val,"=") ; sep=val[2]; next }
/@border=/ { split($0,val,"=") ; border=val[2] ; next }
/@puce=/ { split($0,val,"=") ; sep=val[2]; next }
/@bicolor=/ { split($0,val,"=") ; bicolor=val[2]; next }
/@color1=/ { split($0,val,"=") ; color1=val[2]; next }
/@color2=/ { split($0,val,"=") ; color2=val[2]; next }

#-----------------------------------------------------------------------------
# modes:
#			0 - ligne interprétée
#			1 - ligne inchangée
#			2 - tableau
#			3 - retour au mode 1
#			4 - liste
#			5 - download
#-----------------------------------------------------------------------------
mode==0 { print process($0) }
mode==1 { print $0 }
mode==2 { raw($0,sep) }
mode==3 { mode=1} 
mode==4 { print "<li>" $0 "</li>" }
mode==5 { download($0,sep) }